Count Characters of Selected Text

tell application "Mailsmith"
	try
		set f to selection
		if (class of f is not in {string, character}) or (f = "") or (f = {}) then set f to 0 -- selected mailbox/message or no selected text or mailbox/message  ->  0
		if f is not 0 then -- let's only work on strings
			set g to count of (f as string)
			if g = 1 then
				set Plural to ""
			else
				set Plural to "s"
			end if
			if g < 73 then -- just some fun!
				set theButton to "OK"
			else
				set theButton to "That's much!"
			end if
			display dialog "The selection contains " & (g as string) & ¬
				" character" & Plural & "." buttons {theButton} default button 1 with icon note
		else
			my SelectInfo()
		end if
	on error Errtxt number ErrNo
		beep
		if ErrNo is not -1700 then
			display dialog "The following error has occurred:" & return & return & ¬
				Errtxt & return & "(Error No: " & ErrNo & ")" buttons {"Oops!"} default button 1 with icon caution
		else
			my SelectInfo()
		end if
	end try
end tell


on SelectInfo()
	display dialog "You have to select some text in order to " & ¬
		"use this script!" buttons {"OK"} default button 1 with icon caution
end SelectInfo